;:sys4403:
	*= $c000
	;.opt oo
tmp	=2
	lda #<hi
	ldy #>hi
	jsr $ab1e
	jmp anfang
hi	.byt 13
	.byte "\x93\x12nss vorspanngenerator basic version 1.1"
	.byte " \xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3\xa3"
	.byte " (c)opyright nh 201187 - ein nss programm"
	.byt 13,0
setme	lda #0
	sta 198
c1	lda #0
c2	ldy #0
	jsr $ab1e
	ldy #1
	sty 2
c3	sei
	dey
	bne c4
	ldy #5
	ldx 2
	inx
	cpx #8
	bcc cc
	ldx #0
cc	stx 2
ce	lda !0,x
cd	sta !0+1
	txa
	clc
	adc #4
	and #7
	tax
cf	lda !0,x
cg	sta !0+1
c4	lda 53266
	cmp #150
	bne c4
	ldx #10
c5	dex
	bne c5
ca	lda #0
	sta 53280
	sta 53281
c6	lda 53266
	bne c6
	lda 53265
	bmi c6
cb	lda #0
	sta 53280
	sta 53281
	cli
	lda 198
	beq c3
	jsr 65409
c7	lda #0
c8	ldy #0
	sta 45
	sty 46
	sta 174
	sty 175
c9	jmp 0
text	.byt 11
	.byte "\x93\x11\x11\x11\x11\x11\x11\x11\x11\x11\x11\x11\x98      hi ! this is \x12"
	.byte " nss \x92\x91\x9d\x9d\x9d\x9d\x9d\xa4\xa4\xa4\xa4\xa4\x11 again !\x08"
	.byt 13
	.byte "\x11die nummer eins"
	.byte ", wenn's um software i"
	.byte "n               bayern geht !\x8e"
	brk
table	.byt 0,11,12,15,1,15,12,11
nein	.byte "sorry, aber das programm darf nur aus"
	.byte "   einem sys-befehl beginnen !\x11"
	brk
anfang	lda 45
	sta tmp
	lda 46
	sta tmp+1
	lda tmp
	clc
	adc #ncb
	sta cg+1
	lda tmp+1
	adc #0
	sta cg+2
	lda tmp
	clc
	adc #nca
	sta cd+1
	lda tmp+1
	adc #0
	sta cd+2
	lda tmp
	clc
	adc #ntxt
	sta c1+1
	lda tmp+1
	adc #0
	sta c2+1
	lda tmp
	clc
	adc #ntab
	sta ce+1
	sta cf+1
	lda tmp+1
	adc #0
	sta ce+2
	sta cf+2
	lda 45
	sta tmp
	sta c7+1
	lda 46
	sta tmp+1
	sta c8+1
	lda 2053
	cmp #158
	beq jasys
	lda #<nein
	ldy #>nein
	jmp $ab1e
jasys	lda 122
	pha
	lda 123
	pha
	lda #<2054
	ldy #>2054
	sta 122
	sty 123
	jsr 121
	jsr $bcf3
	jsr $b7f7
	sta c9+2
	pla
	sta 123
	pla
	sta 122
	sty c9+1
	ldy #nein-setme-1
copy	lda setme,y
	sta (tmp),y
	dey
	cpy #-1
	bne copy
	lda 45
	clc
	adc #nein-setme
	sta 45
	bcc klein
	inc 46
klein	ldx tmp
	lda tmp+1
	sta $62
	stx $63
	ldx #$90
	sec
	jsr $bc49
	jsr $bddf
	ldx #0
copy2	lda $100,x
	beq fed
	sta 2054,x
	inx
	bne copy2
fed	lda 2054,x
	cmp #"0"
	bcc ok
	cmp #"9"+1
	bcs ok
	lda #58
	sta 2054,x
ok	rts
ncb	=cb-setme+1
ntxt	=text-setme
ntab	=table-setme
nca	=ca-setme+1